aboutsummaryrefslogtreecommitdiff
path: root/vendor/libghostty-vt/nix/libghostty-vt.nix
blob: fbe87ef0ab20dc8d428beb6b90dfba9fa6cd9805 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
{
  lib,
  stdenv,
  callPackage,
  git,
  pkg-config,
  zig_0_15,
  revision ? "dirty",
  optimize ? "Debug",
}:
stdenv.mkDerivation (finalAttrs: {
  pname = "ghostty";
  version = "0.1.0-dev";

  # We limit source like this to try and reduce the amount of rebuilds as possible
  # thus we only provide the source that is needed for the build
  #
  # NOTE: as of the current moment only linux files are provided,
  # since darwin support is not finished
  src = lib.fileset.toSource {
    root = ../.;
    fileset = lib.fileset.intersection (lib.fileset.fromSource (lib.sources.cleanSource ../.)) (
      lib.fileset.unions [
        ../dist/linux
        ../images
        ../include
        ../po
        ../pkg
        ../src
        ../vendor
        ../build.zig
        ../build.zig.zon
        ../build.zig.zon.nix
      ]
    );
  };

  deps = callPackage ../build.zig.zon.nix {name = "ghostty-cache-${finalAttrs.version}";};

  nativeBuildInputs = [
    git
    pkg-config
    zig_0_15
  ];

  buildInputs = [];

  dontSetZigDefaultFlags = true;

  zigBuildFlags = [
    "--system"
    "${finalAttrs.deps}"
    "-Dversion-string=${finalAttrs.version}-${revision}-nix"
    "-Dcpu=baseline"
    "-Doptimize=${optimize}"
    "-Dapp-runtime=none"
    "-Demit-lib-vt=true"
  ];

  outputs = [
    "out"
    "dev"
  ];

  postInstall = ''
    mkdir -p "$dev/lib"
    mv "$out/lib/libghostty-vt.a" "$dev/lib"
    rm "$out/lib/libghostty-vt.so"
    mv "$out/include" "$dev"
    mv "$out/share" "$dev"

    ln -sf "$out/lib/libghostty-vt.so.0"  "$dev/lib/libghostty-vt.so"
  '';

  postFixup = ''
    substituteInPlace "$dev/share/pkgconfig/libghostty-vt.pc" \
      --replace "$out" "$dev"
  '';

  meta = {
    homepage = "https://ghostty.org";
    license = lib.licenses.mit;
    platforms = zig_0_15.meta.platforms;
  };
})