aboutsummaryrefslogtreecommitdiff
path: root/vendor/libghostty-vt/src/build/combine_archives.zig
diff options
context:
space:
mode:
authorOgulcan Celik <ogulcancelik@gmail.com>2026-05-07 18:29:21 +0300
committerOgulcan Celik <ogulcancelik@gmail.com>2026-05-07 18:29:21 +0300
commitdcfe11a7588fcd42471159453810abc9b7720a57 (patch)
treec32a77266028e73ca2382b96c96f8438a5fcd621 /vendor/libghostty-vt/src/build/combine_archives.zig
parent2dfed860103c4e4505ac7f25def9fe37da1e1e6a (diff)
build: update libghostty-vt vendor
vendor ghostty 063ac3e and remove the musl libc++ link workaround. expose the new selection formatter and hyperlink uri apis for follow-up rendering work. add manual artifact validation for static linux builds.
Diffstat (limited to 'vendor/libghostty-vt/src/build/combine_archives.zig')
-rw-r--r--vendor/libghostty-vt/src/build/combine_archives.zig55
1 files changed, 55 insertions, 0 deletions
diff --git a/vendor/libghostty-vt/src/build/combine_archives.zig b/vendor/libghostty-vt/src/build/combine_archives.zig
new file mode 100644
index 00000000..04ec8e97
--- /dev/null
+++ b/vendor/libghostty-vt/src/build/combine_archives.zig
@@ -0,0 +1,55 @@
+//! Build tool that combines multiple static archives into a single fat
+//! archive using an MRI script piped to `zig ar -M`.
+//!
+//! MRI scripts require stdin piping (`ar -M < script`), which can't be
+//! expressed as a single command in the zig build system's RunStep. The
+//! previous approach used `/bin/sh -c` to do the piping, but that isn't
+//! available on Windows. This tool handles both the script generation
+//! and the piping in a single cross-platform executable.
+//!
+//! Usage: combine_archives <zig_exe> <output.a> <input1.a> [input2.a ...]
+
+const std = @import("std");
+
+pub fn main() !void {
+ var gpa: std.heap.GeneralPurposeAllocator(.{}) = .init;
+ const alloc = gpa.allocator();
+
+ const args = try std.process.argsAlloc(alloc);
+ if (args.len < 4) {
+ std.log.err("usage: combine_archives <zig_exe> <output> <input...>", .{});
+ std.process.exit(1);
+ }
+
+ const zig_exe = args[1];
+ const output_path = args[2];
+ const inputs = args[3..];
+
+ // Build the MRI script.
+ var script: std.ArrayListUnmanaged(u8) = .empty;
+ try script.appendSlice(alloc, "CREATE ");
+ try script.appendSlice(alloc, output_path);
+ try script.append(alloc, '\n');
+ for (inputs) |input| {
+ try script.appendSlice(alloc, "ADDLIB ");
+ try script.appendSlice(alloc, input);
+ try script.append(alloc, '\n');
+ }
+ try script.appendSlice(alloc, "SAVE\nEND\n");
+
+ var child: std.process.Child = .init(&.{ zig_exe, "ar", "-M" }, alloc);
+ child.stdin_behavior = .Pipe;
+ child.stdout_behavior = .Inherit;
+ child.stderr_behavior = .Inherit;
+
+ try child.spawn();
+ try child.stdin.?.writeAll(script.items);
+ child.stdin.?.close();
+ child.stdin = null;
+
+ const term = try child.wait();
+ if (term.Exited != 0) {
+ std.log.err("zig ar -M exited with code {d}", .{term.Exited});
+ std.process.exit(1);
+ }
+}