feat: finish ghostty pane backend integration

1 files changed, 56 insertions, 0 deletions

diff --git a/vendor/libghostty-vt/src/build/HelpStrings.zig b/vendor/libghostty-vt/src/build/HelpStrings.zig
new file mode 100644
index 00000000..96505cab
--- /dev/null
+++ b/vendor/libghostty-vt/src/build/HelpStrings.zig
@@ -0,0 +1,56 @@
+const HelpStrings = @This();
+
+const std = @import("std");
+const Config = @import("Config.zig");
+
+/// The "helpgen" exe.
+exe: *std.Build.Step.Compile,
+
+/// The output path for the help strings.
+output: std.Build.LazyPath,
+
+pub fn init(b: *std.Build, cfg: *const Config) !HelpStrings {
+    const exe = b.addExecutable(.{
+        .name = "helpgen",
+        .root_module = b.createModule(.{
+            .root_source_file = b.path("src/helpgen.zig"),
+            .target = b.graph.host,
+            .strip = false,
+            .omit_frame_pointer = false,
+            .unwind_tables = .sync,
+        }),
+    });
+
+    const help_config = config: {
+        var copy = cfg.*;
+        copy.exe_entrypoint = .helpgen;
+        break :config copy;
+    };
+    const options = b.addOptions();
+    try help_config.addOptions(options);
+    exe.root_module.addOptions("build_options", options);
+
+    const help_run = b.addRunArtifact(exe);
+
+    // Generated Zig files have to end with .zig
+    const wf = b.addWriteFiles();
+    const output = wf.addCopyFile(help_run.captureStdOut(), "helpgen.zig");
+
+    return .{
+        .exe = exe,
+        .output = output,
+    };
+}
+
+/// Add the "help_strings" import.
+pub fn addImport(self: *const HelpStrings, step: *std.Build.Step.Compile) void {
+    self.output.addStepDependencies(&step.step);
+    step.root_module.addAnonymousImport("help_strings", .{
+        .root_source_file = self.output,
+    });
+}
+
+/// Install the help exe
+pub fn install(self: *const HelpStrings) void {
+    self.exe.step.owner.installArtifact(self.exe);
+}